4.1 サンプルプログラム complexmap.bas の追加説明

complexmap.bas

   1 REM 関数 w=z^3 で三角形がどういう図形に写像されるか 
   2 OPTION ARITHMETIC complex
   3 DECLARE EXTERNAL SUB segment
   4 LET w=3
   5 SET WINDOW -w,w,-w,w
   6 DRAW grid(0.5,0.5)
   7 PRINT "複素平面上の三角形を関数 w=z^3 で写す"
   8 PRINT "3点の座標を入力してください。"
   9 CALL cinput(z1)
  10 CALL cinput(z2)
  11 CALL cinput(z3)
  12 CALL segment(z1,z2,2)
  13 CALL segment(z2,z3,3)
  14 CALL segment(z3,z1,4)
  15 END
  16 
  17 REM 線分と線分の像
  18 EXTERNAL SUB segment(z1,z2,col)
  19 OPTION ARITHMETIC complex
  20 LET  i=SQR(-1)
  21 SET LINE COLOR col
  22 REM 線分を描く
  23 SET LINE width 3
  24 PLOT LINES
  25 PLOT LINES : re(z1),im(z1);re(z2),im(z2)
  26 REM 線分上の点の写像による像を描く
  27 SET LINE width 2
  28 FOR t=0 TO 1 STEP 1/128
  29    LET  z=(1-t)*z1+t*z2
  30    CALL MAPPLOT(z)
  31 NEXT t
  32 END SUB
  33 
  34 REM 写像 w=f(z) で写した点をPLOTする
  35 EXTERNAL SUB mapplot(z)
  36 OPTION ARITHMETIC COMPLEX
  37 DEF f(z)=z^3
  38 LET  w=f(z)
  39 PLOT LINES: re(w),im(w);
  40 END SUB
  41 
  42 REM 複素数の入力
  43 EXTERNAL SUB cinput(z)
  44 OPTION ARITHMETIC COMPLEX
  45 INPUT PROMPT "実部虚部を入力: ": x, y
  46 LET  I=SQR(-1)
  47 LET  z=x+I*y
  48 END SUB

このプログラムについては、前回口頭で説明しましたが、 繰り返しておきます。

• 全体が 4 つの部分からなる。
  1. 1〜15行の主プログラム
  2. 17〜33行のサブルーチン segment
  3. 35〜41行のサブルーチン mapplot
  4. 43〜49行のサブルーチン cinput
• サブルーチン cinput は call cinput(z) のように「呼び出す」。 そうすると、画面に「実部虚部を入力:」 と表示し、 キーボードから入力された二つの実数をそれぞれ実部虚部とする複素数を作り、 変数 z に代入して戻って来る。
• サブルーチン segment は call segment(a,b,c) のように呼び出す。 ここで a, b は複素平面上の点を表わす複素数で、 c は色の番号を表わす整数である。 次の二つのことを行う。
  1. a, b を端点とする線分 $S=\texttt{ab}$ を描く。
  2. $S$ を関数 $f$ ($f(z)=z^3$) で写した $f(S)=\{f(z); z\in S\}$ を描く。
• $S$ は真っ直ぐな線分なので、 命令 PLOT LINES 一発で描けるが、 $f(S)$ は一般には「曲がった曲線」なので、次のようにして描いている。 $S$ は、 $S=\{(1-t)$a$+t$b$; t\in[0,1]\}$ であるから、
  $$0=t_0<t_1<\cdots<t_n=1$$
  となる数列 $\{t_j\}_{j=0}^n$ を用意すれば、 $f(S)$ 上の点列 $\{f((1-t_j)$a$+t_j$b$)\}$ が得られる。 これを順に結んだ折れ線を描く。
• z が与えられたとき、 $f($z$)$ を PLOT LINES するのがサブルーチン mapplot の仕事である。