7.1 平面曲線

$x=f(t)$, $y=g(t)$ とパラメーター表示される平面曲線を描くには、 set parametric としてから、 plot f(t),g(t) とすればよい。 このモードから抜けるには set noparametric とする。

• set size ratio 正数 でアスペクト比 (縦の長さ $/$ 横の長さ) を指定できる。
• set size ratio 1 とする代りに set size square とできる (描画領域が正方形になる)。
• 縦と横の縮尺をそろえたい場合は、 set size ratio -1 とする。

特に図形の「形」が気になる場合は、set size ratio -1 は必須かも。 例えば楕円

$$\left\{ \begin{array}{ll} x = 3\cos t\\ y = 2\sin t \end{array} \right. \quad\mbox{($t\in[0,2\pi]$)}$$

やサイクロイド

$$\left\{ \begin{array}{ll} x=a(t-\sin t)\\ y=a(1-\cos t) \end{array} \right. \quad\mbox{($t\in\R$)}.$$

図 11: 楕円 set parametric;set size ratio -1;plot 3*cos(t),2*sin(t)

図 12: cycloid set parametric;set size ratio -1;plot [-8:8] t-sin(t),1-cos(t)

アルキメデス螺旋 $r=\theta$ を二つの方法で描いて比較してみよう。

# archimedes1.gp
set parametric
set samples 200
set xrange [-30:30]
set yrange [-30:30]  
set size square
plot [0:10*pi] t*cos(t),t*sin(t)
pause -1
set term postscript eps color
set output "archimedes1.eps"
replot

# archimedes2.gp
set parametric
set samples 200
set size ratio -1
plot [0:10*pi] t*cos(t),t*sin(t)
pause -1
set term postscript eps color
set output "archimedes2.eps"
replot

図 13: set size square で

図 14: set size ratio -1 で

楕円

# parametric-1.gp --- 楕円
set parametric
a=3
b=2
plot [0:2*pi] a*cos(t),b*sin(t)
pause -1
set term postscript eps color
set output "parametric-1.eps"
replot

図: $x=3\cos t$, $y=2\sin t$ ( $t\in[0,2\pi]$)

双曲線

# parametric-2.gp --- 双曲線
set parametric
set size ratio -1
a=3;b=2
plot [-2:2] a*cosh(t),b*sinh(t),-a*cosh(t),b*sinh(t)
pause -1
set term postscript eps color
set output "parametric-2.eps"
replot

図: $x=\pm3\cosh t$, $y=2\sinh t$ ( $t\in [-2,2]$)